(define dropit
   ((verify empty?) (verify (in-zone? $1)) 
     (while (on-board? n) n) (while (on-board? e) e) 
     (verify (not-piece? $2))
     (while (on-board? w) w (verify (not-piece? $2)))
     back add)
)

(define pp ($1 (verify (and empty? (in-zone? piecehome))) add))

(define placemoves (pp a1) (pp b1) (pp c1) (pp d1) (pp e1) (pp f1) (pp g1)
(pp h1) (pp i1) (pp j1) (pp a10) (pp b10) (pp c10) (pp d10) (pp e10) (pp
f10) (pp g10) (pp h10) (pp i10) (pp j10))

(define leap1    ((verify (not-flag? immobilized)) $1 (verify not-friend?)
add) )

(define leap1move    ((verify (not-flag? immobilized)) $1 (verify empty?)
add) )

(define leap1take    ((verify (not-flag? immobilized)) $1 (verify enemy?)
add) )

(define leap2    ((verify (not-flag? immobilized)) $1 $2 (verify
not-friend?) add) )

(define leap3    ((verify (not-flag? immobilized)) $1 $2 $3 (verify
not-friend?) add) )

(define leap2b ((verify (not-flag? immobilized)) $1 (verify empty?) $2
(verify not-friend?) add) )

(define leap2bmove    ((verify (not-flag? immobilized)) $1 (verify empty?)
$2 (verify empty?) add) )

(define leap2btake    ((verify (not-flag? immobilized)) $1 (verify empty?)
$2 (verify enemy?) add) )

(define leap2move   ((verify (not-flag? immobilized)) $1 $2 (verify empty?) add) )

(define knightmove
(leap2move n ne) (leap2move n nw) (leap2move s se) (leap2move s sw) (leap2move e ne) (leap2move e se) (leap2move w nw) (leap2move w sw) )

(define straightleap2move   ((verify (not-flag? immobilized)) $1 $1 (verify empty?)  add) )

(define leap2take    ((verify (not-flag? immobilized)) $1 $2 (verify enemy?) add) )

(define leap3take    ((verify (not-flag? immobilized)) $1 $2 $3 (verify
enemy?)  add) )

(define straightleap3move   ((verify (not-flag? immobilized)) $1 $1 $1
(verify empty?)  add) )

(define slidemove ((verify (not-flag? immobilized)) $1 (while empty?  add
$1) ) )

(define slidetake ((verify (not-flag? immobilized)) $1 (while empty? $1)
(verify enemy?) add) )

(define bishopmove (slidemove ne) (slidemove nw) (slidemove se) (slidemove sw) )

(define rookmove (slidemove n) (slidemove w) (slidemove e) (slidemove s) )

(define bishoptake (slidetake ne) (slidetake nw) (slidetake se) (slidetake sw) )

(define rooktake (slidetake n) (slidetake w) (slidetake e) (slidetake s) )

(define slide2plus ((verify (not-flag? immobilized)) $1 (verify empty?) $1 (while empty? add $1) (verify enemy?) add ) )

(define slide  ((verify (not-flag? immobilized)) $1 (while empty?  add $1)
(verify not-friend?)  add))

(define rook (slide n) (slide s) (slide e) (slide w) )

(define bishop (slide ne) (slide sw) (slide se) (slide nw) )

(define queen2plus  (slide2plus n) (slide2plus s) (slide2plus e) (slide2plus w) (slide2plus ne) (slide2plus sw) (slide2plus se) (slide2plus nw) )

(define crookedslide (
(verify (not-flag? immobilized))
(while (on-board? $1) $1
(if empty? add else (verify not-friend?) add (verify false))
(if (on-board? $2) $2 else (verify false)) (if empty? add else (verify not-friend?) add (verify false)))
))

(define slide3 ((verify (not-flag? immobilized)) $1 (if enemy? add else (verify empty?) add $1) (if enemy? add else (verify empty?) add $1) (if enemy? add else (verify empty?) add)))

(define queen3 (slide3 n) (slide3 s) (slide3 e) (slide3 w) (slide3 ne) (slide3 sw) (slide3 se) (slide3 nw) )

(define ride ((verify (not-flag? immobilized)) $1 $2 (while empty? add $1 $2) (verify not-friend?) add))

(define switchride ((verify (not-flag? immobilized)) $1 (if enemy? add (verify false) else (verify empty?) add $1 $1) (while empty? add $1 $1) (verify not-friend?) add))

(define slide2  ((verify (not-flag? immobilized)) $1 (verify not-friend?)
add (verify empty?) $1 (verify not-friend?)  add))

(define slide2move  ((verify (not-flag? immobilized)) $1 (verify empty?) add $1 (verify empty?)  add))

(define queen2move (slide2move n) (slide2move s) (slide2move w) (slide2move e) (slide2move ne) (slide2move nw) (slide2move se) (slide2move sw) )

(define exact2move  ((verify (not-flag? immobilized)) $1 (verify empty?) $1 (verify empty?)  add))

(define move23  ((verify (not-flag? immobilized)) $1 (verify empty?) $1
(verify empty?) add $1 (verify empty?) add))

(define slide2take  ((verify (not-flag? immobilized)) $1 (if enemy? add else (verify empty?) $1 (verify enemy?)  add)))

(define slide-cannon   ( (verify (not-flag? immobilized)) $1 (while empty?
add $1) $1 (while empty? $1) (verify enemy?) add))

(define slide-cannon-capture   ( (verify (not-flag? immobilized)) $1 (while empty? $1) $1 (while empty? $1) (verify enemy?) add))

(define freeleap-slidemove ((verify (not-flag? immobilized)) (while
on-board? $1 (if empty? add) ) ) )

(define slide-falcon ((verify (not-flag? immobilized)) (while on-board? (if (and enemy? (empty? $1)) $1 (capture $2) add else (if empty? add) ) $1 ) ) )

 (define slide-falcon-line ((verify (not-flag? immobilized)) (while on-board? (if (and enemy? (empty? $1)) $1 mark (while (enemy? $2) (capture $2) $2 ) back add else (if empty? add) ) $1 ) ) )

(define slide-falcon-convert 
(
(verify (not-flag? immobilized))
 (while on-board? 
(if (and enemy? (not loyal) (not-piece? King) (empty? $1)) flip $1 add else
(if (and enemy? (piece? King) (empty? $1)) capture $1 add))
$1)
) )

(define straightleap2  ( (verify (not-flag? immobilized)) $1 $1 (verify
not-friend?) add) )

(define straightleap3  ( (verify (not-flag? immobilized)) $1 $1 $1 (verify
not-friend?) add) )

(define straightleapmove123  (
(verify (not-flag? immobilized))
$1 (if empty? add) 
$1 (if empty? add)
$1 (if empty? add) ))

(define twosquaremove ((verify (not-flag? immobilized)) $1 (verify empty?)
add $1 (verify empty?) add))

(define leap3 ((verify (not-flag? immobilized)) $1 $2 $3 (verify
not-friend?) add) )

(define tripleslide (
(verify (not-flag? immobilized))
(while (and (empty? $1) (on-board? $1)) $1 add) (if (and (enemy? $1)
(on-board? $1)) $1 add)
back
(if (and (on-board? $2) (enemy? $2)) $2 add else (if (and (on-board? $2)
(empty? $2)) $2 add (while (and (empty? $1) (on-board? $1)) $1 add) (if (and (enemy? $1) (on-board? $1)) $1 add)))
back
(if (and (on-board? $3) (enemy? $3)) $3 add else (if (and (on-board? $3)
(empty? $3)) $3 add (while (and (empty? $1) (on-board? $1)) $1 add) (if (and (enemy? $1) (on-board? $1)) $1 add)))
))

(define bentslide (
(verify (not-flag? immobilized))
(if (and (on-board? $2) (enemy? $2)) $2 add else (if (and (on-board? $2)
(empty? $2)) $2 add (while (and (empty? $1) (on-board? $1)) $1 add) (if (and (enemy? $1) (on-board? $1)) $1 add)))
back
(if (and (on-board? $3) (enemy? $3)) $3 add else (if (and (on-board? $3)
(empty? $3)) $3 add (while (and (empty? $1) (on-board? $1)) $1 add) (if (and (enemy? $1) (on-board? $1)) $1 add)))
))

(define lineshoot ( (verify (not-flag? immobilized)) $1 (while empty? $1)
(if (and enemy? (piece? King)) add else (verify (and enemy? (not armored))) capture back add) )
)

;(define lineshoot3 ( (verify (not-flag? immobilized)) $1 (if (and enemy? (piece? King)) add else (if enemy? capture else (verify empty?) $1)) (if (and enemy? (piece? King)) add else (if enemy? capture else (verify empty?) $1)) (if (and enemy? (piece? King)) add else (if enemy? capture)) back add))


(define leap1swapconvert
    ( (verify (not-flag? immobilized)) $1 (verify (and enemy? (not loyal))) to cascade back
flip (go to) add))

(define leap2swapconvert
    ( (verify (not-flag? immobilized)) $1 $2 (verify (and enemy? (not loyal))) to cascade back
flip (go to) add))

(define longconvertslide  ( (verify (not-flag? immobilized)) $1 (while (and empty? (empty? $1)) add $1) (if (and empty? (enemy? $1) (not-piece? King $1) (not (loyal $1))) (flip $1) add else (if (and empty? (enemy? $1) (piece? King $1)) (capture $1) add else (verify empty?) add))))

(define diploslide  ( (verify (not-flag? immobilized)) $1 (verify empty?)
(if (and (enemy? $1) (piece? King $1)) (capture $1) else (if (and (enemy? $1) (not (loyal $1))) (flip $1))) add $1 (verify empty?) (if (and (enemy? $1) (piece? King $1)) (capture $1) else (if (and (enemy? $1) (not (loyal $1))) (flip $1))) add $1 (verify empty?) (if (and (enemy? $1) (piece? King $1)) (capture $1) else (if (and (enemy? $1) (not (loyal $1))) (flip $1))) add ))

(define leap1proxconvert (
(verify (not-flag? immobilized)) $1 (verify empty?)
(if (and (enemy? n) (piece? King n)) (capture n) else (if (and (enemy? n) (not (loyal n))) (flip n)))
(if (and (enemy? s) (piece? King s)) (capture s) else (if (and (enemy? s) (not (loyal s))) (flip s)))
(if (and (enemy? e) (piece? King e)) (capture e) else (if (and (enemy? e) (not (loyal e))) (flip e)))
(if (and (enemy? w) (piece? King w)) (capture w) else (if (and (enemy? w) (not (loyal w))) (flip w)))
(if (and (enemy? ne) (piece? King ne)) (capture ne) else (if (and (enemy? ne) (not (loyal ne))) (flip ne)))
(if (and (enemy? nw) (piece? King nw)) (capture nw) else (if (and (enemy? nw) (not (loyal nw))) (flip nw)))
(if (and (enemy? se) (piece? King se)) (capture se) else (if (and (enemy? se) (not (loyal se))) (flip se)))
(if (and (enemy? sw) (piece? King sw)) (capture sw) else (if (and (enemy? sw) (not (loyal sw))) (flip sw)))
add))

(define decimate 
(if (not inert) 
(if (enemy? n) (capture n) )
(if (enemy? s) (capture s) )
(if (enemy? e) (capture e) )
(if (enemy? w) (capture w) )
(if (enemy? ne) (capture ne) )
(if (enemy? sw) (capture sw) )
(if (enemy? se) (capture se) )
(if (enemy? nw) (capture nw) )
add
else add)
)

(define orthodecimate 
(if (not inert) 
(if (enemy? n) (capture n) )
(if (enemy? s) (capture s) )
(if (enemy? e) (capture e) )
(if (enemy? w) (capture w) )
add
else add)
)

(define diagdecimate 
(if (not inert) 
(if (enemy? ne) (capture ne) )
(if (enemy? sw) (capture sw) )
(if (enemy? se) (capture se) )
(if (enemy? nw) (capture nw) )
add
else add)
)

(define leap2decimate 
( (verify (not-flag? immobilized)) $1 $2 (verify enemy?) (decimate) ))

(define leap1decimate 
( (verify (not-flag? immobilized)) $1 (verify enemy?) (decimate) ))

(define straightleap3decimate 
( (verify (not-flag? immobilized)) $1 $1 $1 (verify enemy?) (decimate) ))

(define slidedecimate 
( (verify (not-flag? immobilized)) $1 (while empty? $1) (verify enemy?) (decimate) ))

(define slide2decimate 
( (verify (not-flag? immobilized)) $1 (if enemy? (decimate) else (verify empty?) $1) (verify enemy?) (decimate) ))


(define knightdecimate 
(leap2decimate n ne) (leap2decimate n nw) (leap2decimate s  se) (leap2decimate s sw) (leap2decimate e ne) (leap2decimate e se) (leap2decimate w nw) (leap2decimate w sw)
)

(define ferzdecimate (leap1decimate ne) (leap1decimate nw) (leap1decimate se) (leap1decimate sw) )

(define wazirdecimate (leap1decimate n) (leap1decimate w) (leap1decimate e) (leap1decimate s) )

(define alfildecimate (leap2decimate ne ne) (leap2decimate nw nw) (leap2decimate se se) (leap2decimate sw sw) )

(define dabbabadecimate (leap2decimate n n) (leap2decimate w w) (leap2decimate e e) (leap2decimate s s) )

(define jerboadecimate (straightleap3decimate ne) (straightleap3decimate nw) (straightleap3decimate se) (straightleap3decimate sw) )

(define llamadecimate (straightleap3decimate n) (straightleap3decimate w) (straightleap3decimate e) (straightleap3decimate s) )

(define bishopdecimate 
(slidedecimate ne) (slidedecimate nw) (slidedecimate se) (slidedecimate sw) )

(define rookdecimate 
(slidedecimate n) (slidedecimate w) (slidedecimate e) (slidedecimate s) )

(define queen2decimate 
(slide2decimate n) (slide2decimate w) (slide2decimate e) (slide2decimate s) (slide2decimate ne) (slide2decimate nw) (slide2decimate se) (slide2decimate sw) )

(define approachtake  ((verify (not-flag? immobilized)) $1 (while (and
empty? (empty? $1)) $1) (if (enemy? $1) (capture $1) add)))

 
(define hookmove
   (
 (verify (not-flag? immobilized))
$1 mark (verify empty?)
       (while (and (on-board? $2) (empty? $2)) $2 add)
           (if (and (on-board? $2) (not-friend? $2)) $2 add back else back)
$1 mark (verify empty?)
       (while (and (on-board? $2) (empty? $2)) $2 add)
           (if (and (on-board? $2) (not-friend? $2)) $2 add back else back)
$1 mark (verify empty?)
       (while (and (on-board? $2) (empty? $2)) $2 add)
           (if (and (on-board? $2) (not-friend? $2)) $2 add back else back)
$1 mark (verify empty?)
       (while (and (on-board? $2) (empty? $2)) $2 add)
           (if (and (on-board? $2) (not-friend? $2)) $2 add back else back)
$1 mark (verify empty?)
       (while (and (on-board? $2) (empty? $2)) $2 add)
           (if (and (on-board? $2) (not-friend? $2)) $2 add back else back)
$1 mark (verify empty?)
       (while (and (on-board? $2) (empty? $2)) $2 add)
           (if (and (on-board? $2) (not-friend? $2)) $2 add back else back)
$1 mark (verify empty?)
       (while (and (on-board? $2) (empty? $2)) $2 add)
           (if (and (on-board? $2) (not-friend? $2)) $2 add back else back)
$1 mark (verify empty?)
       (while (and (on-board? $2) (empty? $2)) $2 add)
           (if (and (on-board? $2) (not-friend? $2)) $2 add back else back)
$1 mark (verify empty?)
       (while (and (on-board? $2) (empty? $2)) $2 add)
           (if (and (on-board? $2) (not-friend? $2)) $2 add back else back)
   )
)                 

(define prox
(if (and (not (shielded n))(enemy? n)) (capture n)) 
(if (and (not (shielded s))(enemy? s)) (capture s)) 
(if (and (not (shielded s))(enemy? e)) (capture e)) 
(if (and (not (shielded w))(enemy? w)) (capture w)) 
(if (and (not (shielded ne))(enemy? ne)) (capture ne)) 
(if (and (not (shielded nw))(enemy? nw)) (capture nw)) 
(if (and (not (shielded sw))(enemy? sw)) (capture sw)) 
(if (and (not (shielded se))(enemy? se)) (capture se)) 
add )

(define orthoprox 
(if (and (not (shielded n))(enemy? n)) (capture n)) 
(if (and (not (shielded s))(enemy? s)) (capture s)) 
(if (and (not (shielded s))(enemy? e)) (capture e)) 
(if (and (not (shielded w))(enemy? w)) (capture w)) 
add )

(define diagprox 
(if (and (not (shielded ne))(enemy? ne)) (capture ne)) 
(if (and (not (shielded nw))(enemy? nw)) (capture nw)) 
(if (and (not (shielded sw))(enemy? sw)) (capture sw)) 
(if (and (not (shielded se))(enemy? se)) (capture se)) 
add )

(define leap2prox ( (verify (not-flag? immobilized)) $1 $2 (verify empty?) (prox) ))

(define leap2orthoprox ( (verify (not-flag? immobilized)) $1 $2 (verify empty?) (orthoprox) ))

(define leap2diagprox ( (verify (not-flag? immobilized)) $1 $2 (verify empty?) (diagprox) ))

(define proximitystep ( (verify (not-flag? immobilized)) $1 (verify empty?) (prox)) )

(define wazirprox (proximitystep n) (proximitystep s) (proximitystep e)(proximitystep w) )

(define ferzprox (proximitystep ne) (proximitystep sw) (proximitystep se)(proximitystep nw) )

;   proximity slide that must stop at first adjacent enemy unit
(define proximityslide
(
(verify (not-flag? immobilized))
 $1  (while (and empty? (not-enemy? n) (not-enemy? ne) (not-enemy? e)
(not-enemy? se) (not-enemy? s) (not-enemy? sw) (not-enemy? w) (not-enemy?
nw)) (prox) $1)
   (verify empty?) (prox)
 ) )

;   proximity slide of range 3 that must stop at first adjacent enemy unit
(define proximityslide3
(
(verify (not-flag? immobilized))
 $1  (if (and empty? (not-enemy? n) (not-enemy? ne) (not-enemy? e) (not-enemy? se) (not-enemy? s) (not-enemy? sw) (not-enemy? w) (not-enemy?
nw)) (prox) $1)
     (if (and empty? (not-enemy? n) (not-enemy? ne) (not-enemy? e) (not-enemy? se) (not-enemy? s) (not-enemy? sw) (not-enemy? w) (not-enemy?
nw)) (prox) $1)
   (verify empty?) (prox)
 ) )

;   orthoproximity slide that must stop at first orthogonally adjacent enemy unit
(define orthoproximityslide
(
(verify (not-flag? immobilized))
 $1 
   (while (and empty? (not-enemy? $2) (not-enemy? $3) (not-enemy? $4)
(not-enemy? $5) )
      (if (enemy? $2) (capture $2)) (if (enemy? $3) (capture $3)) (if
(enemy? $4) (capture $4)) (if (enemy? $5) (capture $5))  add $1
   )
         (verify empty?) (if (enemy? $2) (capture $2)) (if (enemy? $3)
(capture $3)) (if (enemy? $4) (capture $4)) (if (enemy? $5) (capture $5))
add
 ) )

;  proximity slide with no limit
(define freeproximityslide ( (verify (not-flag? immobilized)) $1 (while
empty? (if (enemy? $1) (capture $1)) (if (enemy? $2) (capture $2)) (if
(enemy? $3) (capture $3)) (if (enemy? $4) (capture $4)) (if (enemy? $5)
(capture $5)) (if (enemy? $6) (capture $6)) (if (enemy? $7) (capture $7))
(if (enemy? $8) (capture $8)) add $1) ) )

; does not have to stop at adjacent units -- can capture by prox on empty square or by replacement capture
(define ortho-prox-decimate-slide (
(verify (not-flag? immobilized))
 $1  (while empty? (orthoprox) $1) (verify enemy?) (orthodecimate)
 ) )

; does not have to stop at adjacent units -- can capture by prox on empty square or by replacement capture
(define diag-prox-decimate-slide (
(verify (not-flag? immobilized))
 $1  (while empty? (diagprox) $1) (verify enemy?) (diagdecimate)
 ) )

(define jug3 ( (verify (not-flag? immobilized)) $1 (verify not-friend?) add
back $1 (verify not-friend?) (if enemy? capture) $1 (verify not-friend?) add
back $1 (verify not-friend?) (if enemy? capture) $1 (verify not-friend?) (if
enemy? capture) $1 (verify not-friend?) add ) )

(define moveleap1  (  (verify (not-flag? immobilized)) $1 (verify empty?)
add) ) 

(define shoot2 ( (verify (not-flag? immobilized)) $1 (if (and enemy? (not armored)) capture back
add else (verify empty?) $1 (if (and enemy? (piece? King)) add else (verify (and enemy? (not armored))) capture back add) ) ) )

(define shoot3 ( (verify (not-flag? immobilized))
 $1
(if (and enemy? (piece? King)) add) (if (and enemy? (not armored)) capture back add else (verify empty?) $1)
(if (and enemy? (piece? King)) add) (if (and enemy? (not armored)) capture back add else (verify empty?) $1)
(if (and enemy? (piece? King)) add) (if (and enemy? (not armored)) capture back add)
) )


(define leap2shoot ( (verify (not-flag? immobilized)) $1 $2 (if (and enemy?
(piece? King)) add else (verify (and enemy? (not armored))) capture back add) ) )

(define protoministerstep11 ( (verify (not-flag? immobilized)) $1 (if enemy? capture $2 (verify not-friend?) add else back $1 (verify empty?) $2 (verify not-friend?) add)))

(define protoministerstep12 ((verify (not-flag? immobilized)) $1 (if enemy? capture $2 (verify empty?) $2 (verify not-friend?) add else back $1 (verify empty?) $2 (verify empty?) $2 (verify not-friend?) add)))

(define protoministerstep12retrace ((verify (not-flag? immobilized)) $1 (if enemy? capture $2 (verify empty?) $2 (verify not-friend?) add)))

(define protoministerstep21 ((verify (not-flag? immobilized)) $1 (verify empty?) $1 (if enemy? capture $2 (verify not-friend?) add else back $1 (verify empty?) $1 (verify empty?) $2 (verify not-friend?) add)))

(define protoministerstep22 ((verify (not-flag? immobilized)) $1 (verify empty?) $1 (if enemy? capture $2 (verify empty?) $2 (verify not-friend?) add else back $1 (verify empty?) $1 (verify empty?) $2 (verify empty?) $2 (verify not-friend?) add)))

(define ministerstep

     (protoministerstep11 ne ne)
     (protoministerstep11 ne nw)
     (protoministerstep11 ne se)

     (protoministerstep11 nw ne)
     (protoministerstep11 nw nw)
     (protoministerstep11 nw sw)

     (protoministerstep11 se ne)
     (protoministerstep11 se se)
     (protoministerstep11 se sw)

     (protoministerstep11 sw nw)
     (protoministerstep11 sw se)
     (protoministerstep11 sw sw)

     (protoministerstep22 ne ne)
     (protoministerstep22 ne nw)
     (protoministerstep22 ne se)

     (protoministerstep22 nw ne)
     (protoministerstep22 nw nw)
     (protoministerstep22 nw sw)

     (protoministerstep22 se ne)
     (protoministerstep22 se se)
     (protoministerstep22 se sw)

     (protoministerstep22 sw nw)
     (protoministerstep22 sw se)
     (protoministerstep22 sw sw)

     (protoministerstep12 ne ne)
     (protoministerstep12 ne nw)
     (protoministerstep12 ne se)
     (protoministerstep12retrace  ne sw)

     (protoministerstep12 nw ne)
     (protoministerstep12 nw nw)
     (protoministerstep12 nw sw)
     (protoministerstep12retrace  nw se)

     (protoministerstep12 se ne)
     (protoministerstep12 se se)
     (protoministerstep12 se sw)
     (protoministerstep12retrace  se nw)

     (protoministerstep12 sw nw)
     (protoministerstep12 sw se)
     (protoministerstep12 sw sw)
     (protoministerstep12retrace  sw ne)

     (protoministerstep21 ne ne)
     (protoministerstep21  ne nw)
     (protoministerstep21  ne se)
     (protoministerstep21  ne sw)

     (protoministerstep21  nw ne)
     (protoministerstep21  nw nw)
     (protoministerstep21  nw sw)
     (protoministerstep21  nw se)

     (protoministerstep21  se ne)
     (protoministerstep21  se se)
     (protoministerstep21  se sw)
     (protoministerstep21  se nw)

     (protoministerstep21  sw nw)
     (protoministerstep21  sw se)
     (protoministerstep21  sw sw)
     (protoministerstep21  sw ne)
)

(define chamberlainstep

     (protoministerstep11 n n)
     (protoministerstep11 n e)
     (protoministerstep11 n w)

     (protoministerstep11 s e)
     (protoministerstep11 s w)
     (protoministerstep11 s s)

     (protoministerstep11 e e)
     (protoministerstep11 e s)
     (protoministerstep11 e n)

     (protoministerstep11 w w)
     (protoministerstep11 w n)
     (protoministerstep11 w s)

     (protoministerstep22  n n)
     (protoministerstep22  n e)
     (protoministerstep22  n w)

     (protoministerstep22  s e)
     (protoministerstep22  s w)
     (protoministerstep22  s s)

     (protoministerstep22  e e)
     (protoministerstep22  e s)
     (protoministerstep22  e n)

     (protoministerstep22  w w)
     (protoministerstep22  w n)
     (protoministerstep22  w s)

     (protoministerstep12 w w)
     (protoministerstep12 w n)
     (protoministerstep12 w s)
     (protoministerstep12retrace  w e)

     (protoministerstep12retrace  n s)
     (protoministerstep12 n e)
     (protoministerstep12 n w)
     (protoministerstep12 n n)

     (protoministerstep12 s s)
     (protoministerstep12 s e)
     (protoministerstep12 s w)
     (protoministerstep12retrace  s n)

     (protoministerstep12 e e)
     (protoministerstep12retrace  e w)
     (protoministerstep12 e s)
     (protoministerstep12 e n)

     (protoministerstep21 w w)
     (protoministerstep21 w n)
     (protoministerstep21 w s)
     (protoministerstep21 w e)

     (protoministerstep21 n s)
     (protoministerstep21 n e)
     (protoministerstep21 n w)
     (protoministerstep21 n n)

     (protoministerstep21 s s)
     (protoministerstep21 s e)
     (protoministerstep21 s w)
     (protoministerstep21 s n)

     (protoministerstep21 e e)
     (protoministerstep21 e w)
     (protoministerstep21 e s)
     (protoministerstep21 e n)
)

(define protoviceroystep1 ( (verify (not-flag? immobilized)) $1 (if enemy?
capture $2 (verify not-friend?) add)))

(define protoviceroystep2 ( (verify (not-flag? immobilized)) $1 (verify
empty?) $2 (verify not-friend?) add))

(define viceroystep

     (protoviceroystep2 n ne)
     (protoviceroystep2 n n)
     (protoviceroystep2 n nw)

     (protoviceroystep2 s se)
     (protoviceroystep2 s s)
     (protoviceroystep2 s sw)

     (protoviceroystep2 e ne)
     (protoviceroystep2 e e)
     (protoviceroystep2 e se)

     (protoviceroystep2 w nw)
     (protoviceroystep2 w w)
     (protoviceroystep2 w sw)

     (protoviceroystep2 ne ne)
     (protoviceroystep2 ne n)
     (protoviceroystep2 ne e)

     (protoviceroystep2 nw nw)
     (protoviceroystep2 nw n)
     (protoviceroystep2 nw w)

     (protoviceroystep2 se se)
     (protoviceroystep2 se s)
     (protoviceroystep2 se e)

     (protoviceroystep2 sw sw)
     (protoviceroystep2 sw w)
     (protoviceroystep2 sw s)

     (protoviceroystep1 n n)
     (protoviceroystep1 n e)
     (protoviceroystep1 n w)
     (protoviceroystep1 n ne)
     (protoviceroystep1 n nw)
     (protoviceroystep1 n se)
     (protoviceroystep1 n sw)

     (protoviceroystep1 s s)
     (protoviceroystep1 s e)
     (protoviceroystep1 s w)
     (protoviceroystep1 s ne)
     (protoviceroystep1 s nw)
     (protoviceroystep1 s se)
     (protoviceroystep1 s sw)

     (protoviceroystep1 e n)
     (protoviceroystep1 e s)
     (protoviceroystep1 e e)
     (protoviceroystep1 e ne)
     (protoviceroystep1 e nw)
     (protoviceroystep1 e se)
     (protoviceroystep1 e sw)

     (protoviceroystep1 w n)
     (protoviceroystep1 w s)
     (protoviceroystep1 w w)
     (protoviceroystep1 w ne)
     (protoviceroystep1 w nw)
     (protoviceroystep1 w se)
     (protoviceroystep1 w sw)

     (protoviceroystep1 ne n)
     (protoviceroystep1 ne s)
     (protoviceroystep1 ne e)
     (protoviceroystep1 ne w)
     (protoviceroystep1 ne ne)
     (protoviceroystep1 ne nw)
     (protoviceroystep1 ne se)

     (protoviceroystep1 nw n)
     (protoviceroystep1 nw s)
     (protoviceroystep1 nw e)
     (protoviceroystep1 nw w)
     (protoviceroystep1 nw ne)
     (protoviceroystep1 nw nw)
     (protoviceroystep1 nw sw)

     (protoviceroystep1 se n)
     (protoviceroystep1 se s)
     (protoviceroystep1 se e)
     (protoviceroystep1 se w)
     (protoviceroystep1 se ne)
     (protoviceroystep1 se se)
     (protoviceroystep1 se sw)

     (protoviceroystep1 sw n)
     (protoviceroystep1 sw s)
     (protoviceroystep1 sw e)
     (protoviceroystep1 sw w)
     (protoviceroystep1 sw nw)
     (protoviceroystep1 sw se)
     (protoviceroystep1 sw sw) )


; knight-type cavalry
(define protocavleap ((verify (not-flag? immobilized)) $1 $2 (if empty? add
$3 $4 (verify not-friend?) add else back $1 $2 (verify not-friend?) add)))

; chinese-horse-type cavalry
; (define protocavleap ((verify (not-flag? immobilized)) $1 (verify empty?) $2 (if empty? add $3 (if empty? $4) (verify not-friend?) add else back $1 (verify empty?) $2 (verify not-friend?) add)))

(define cavleap
     (protocavleap n ne n ne)
     (protocavleap n ne n nw)
     (protocavleap n ne e ne)
     (protocavleap n ne e se)
     (protocavleap n ne s se)
     (protocavleap n ne w sw)
     (protocavleap n ne w nw)

     (protocavleap n nw n ne)
     (protocavleap n nw n nw)
     (protocavleap n nw e ne)
     (protocavleap n nw s sw)
     (protocavleap n nw s se)
     (protocavleap n nw w sw)
     (protocavleap n nw w nw)

     (protocavleap e ne n ne)
     (protocavleap e ne n nw)
     (protocavleap e ne e ne)
     (protocavleap e ne e se)
     (protocavleap e ne s sw)
     (protocavleap e ne s se)
     (protocavleap e ne w nw)

     (protocavleap e se n ne)
     (protocavleap e se n nw)
     (protocavleap e se e ne)
     (protocavleap e se e se)
     (protocavleap e se s sw)
     (protocavleap e se s se)
     (protocavleap e se w sw)

     (protocavleap s sw n nw)
     (protocavleap s sw e ne)
     (protocavleap s sw e se)
     (protocavleap s sw s sw)
     (protocavleap s sw s se)
     (protocavleap s sw w sw)
     (protocavleap s sw w nw)

     (protocavleap s se n ne)
     (protocavleap s se e ne)
     (protocavleap s se e se)
     (protocavleap s se s sw)
     (protocavleap s se s se)
     (protocavleap s se w sw)
     (protocavleap s se w nw)

     (protocavleap w sw n ne)
     (protocavleap w sw n nw)
     (protocavleap w sw e se)
     (protocavleap w sw s sw)
     (protocavleap w sw s se)
     (protocavleap w sw w sw)
     (protocavleap w sw w nw)

     (protocavleap w nw n ne)
     (protocavleap w nw n nw)
     (protocavleap w nw e ne)
     (protocavleap w nw s sw)
     (protocavleap w nw s se)
     (protocavleap w nw w sw)
     (protocavleap w nw w nw)
)

(define protomedusatest
        mark  (if (on-board? $1) $1)
              (if (and enemy? (or (piece? Medusa) (piece? Wizard))) (set-flag immobilized true)
back else back) )

(define medusatest
         (protomedusatest n)
         (protomedusatest ne)
         (protomedusatest e)
         (protomedusatest se)
         (protomedusatest s)
         (protomedusatest sw)
         (protomedusatest w)
         (protomedusatest nw)  )

(define protobasilisktest
        mark  (if (on-board? $1) $1 else back)
              (if (on-board? $2) $2 (if (and enemy? (piece? Basilisk))
(set-flag immobilized true)) else back) back)

(define basilisktest
         (protobasilisktest n ne)
         (protobasilisktest ne e)
         (protobasilisktest e se)
         (protobasilisktest se s)
         (protobasilisktest s sw)
         (protobasilisktest sw w)
         (protobasilisktest w nw)
         (protobasilisktest nw n)  )

(define protogorgonatest
        mark  (if (on-board? $1) $1)
              (while (and empty? (on-board? $1) ) $1)
              (if (and enemy? (piece? Gorgona) ) (set-flag immobilized true)
back else back )
          )

(define gorgonatest
         (protogorgonatest n)
         (protogorgonatest ne)
         (protogorgonatest e)
         (protogorgonatest se)
         (protogorgonatest s)
         (protogorgonatest sw)
         (protogorgonatest w)
         (protogorgonatest nw)  )

(define protocyclopstest
        mark  (if (on-board? $1) $1)
              (while (and empty? (on-board? $1) ) $1)
              (if (and enemy? (piece? Cyclops) ) (set-flag immobilized true)
back else back )
          )

(define cyclopstest
         (protocyclopstest ne)
         (protocyclopstest se)
         (protocyclopstest sw)
         (protocyclopstest nw)  )

(define protochimaeratest
        mark  (if (on-board? $1) $1)
              (while (and empty? (on-board? $1) ) $1)
              (if (and enemy? (piece? Chimaera) ) (set-flag immobilized
true) back else back )
          )

(define chimaeratest
         (protochimaeratest n)
         (protochimaeratest e)
         (protochimaeratest s)
         (protochimaeratest w)  )

(define immobilizertest (medusatest) (gorgonatest) (basilisktest)
(cyclopstest) (chimaeratest))

(define knight (leap2 n ne) (leap2 n nw) (leap2 s se) (leap2 s sw) (leap2 e ne) (leap2 e se) (leap2 w nw) (leap2 w sw) )

(define camel (leap3 n n ne) (leap3 n n nw) (leap3 s s se) (leap3 s s sw) (leap3 e e ne) (leap3 e e se) (leap3 w w nw) (leap3 w w sw) )

(define wazir (leap1 n) (leap1 s) (leap1 e) (leap1 w) )

(define dabbaba (straightleap2 n) (straightleap2 s) (straightleap2 e) (straightleap2 w) )

(define jerboa (straightleap3 ne) (straightleap3 sw) (straightleap3 se) (straightleap3 nw) )

(define llama (straightleap3 n) (straightleap3 w) (straightleap3 s) (straightleap3 e) )

(define wazirmove (leap1move n) (leap1move s) (leap1move e) (leap1move w) )

(define ferzmove (leap1move ne) (leap1move sw) (leap1move se) (leap1move nw) )

(define alfilmove (straightleap2move ne) (straightleap2move nw) (straightleap2move se) (straightleap2move sw) )

(define jerboamove (straightleap3move ne) (straightleap3move nw) (straightleap3move se) (straightleap3move sw) )

(define dabbabamove (straightleap2move n) (straightleap2move w) (straightleap2move e) (straightleap2move s) )

(define llamamove (straightleap3move n) (straightleap3move w) (straightleap3move e) (straightleap3move s) )

(define ferz (leap1 ne) (leap1 sw) (leap1 se) (leap1 nw) )

(define alfil (straightleap2 ne) (straightleap2 sw) (straightleap2 se) (straightleap2 nw) )

(define knightrider (ride n ne) (ride n nw) (ride s se) (ride s sw) (ride e ne) (ride e se) (ride w nw) (ride w sw) )

(define dabbabarider (ride e e) (ride w w) (ride n n) (ride s s) )

(define switching-dabbabarider (switchride e) (switchride w) (switchride s) (switchride n) )

(define alfilrider (ride ne ne) (ride sw sw) (ride nw nw) (ride se se) )

(define pawn-add (if (in-zone? promotion-zone) (add Wizard) else add) )

(define pawn-move-1 ((verify (not-flag? immobilized)) $1 (verify empty?)
(pawn-add)) )

(define pawn-move-straight2 ((verify (not-flag? immobilized)) $1 (verify
empty?) (pawn-add) $1 (verify empty?) (pawn-add)) )

(define pawn-move-leap2 ((verify (not-flag? immobilized)) $1 $2 (verify
empty?) (pawn-add)) )

(define pawn-move-hop1 ((verify (not-flag? immobilized)) $1 (verify (not empty?)) $1 (verify empty?) (pawn-add)) )

(define pawn-move-bent2 ((verify (not-flag? immobilized)) $1 (verify
not-enemy?) $2 (verify empty?) (pawn-add)) )

(define pawn-move-W (pawn-move-1 n) (pawn-move-1 s) (pawn-move-1 e)
(pawn-move-1 w))

(define pawn-move-WL (pawn-move-1 n) (pawn-move-1 s) (pawn-move-1 e)
(pawn-move-1 w) (pawn-move-hop1 n) (pawn-move-hop1 s) (pawn-move-hop1 e)
(pawn-move-hop1 w))

(define pawn-move-WJ (pawn-move-1 n) (pawn-move-1 s) (pawn-move-1 e)
(pawn-move-1 w) (pawn-move-hop1 ne) (pawn-move-hop1 sw) (pawn-move-hop1 se)
(pawn-move-hop1 nw))

(define pawn-move-FWL (pawn-move-1 ne) (pawn-move-1 sw) (pawn-move-1 se)
(pawn-move-1 nw) (pawn-move-1 n) (pawn-move-1 s) (pawn-move-1 e)
(pawn-move-1 w) (pawn-move-hop1 n) (pawn-move-hop1 s) (pawn-move-hop1 e)
(pawn-move-hop1 w))

(define pawn-move-FWLJ (pawn-move-1 ne) (pawn-move-1 sw) (pawn-move-1 se)
(pawn-move-1 nw) (pawn-move-1 n) (pawn-move-1 s) (pawn-move-1 e)
(pawn-move-1 w) (pawn-move-hop1 n) (pawn-move-hop1 s) (pawn-move-hop1 e)
(pawn-move-hop1 w) (pawn-move-hop1 ne) (pawn-move-hop1 sw) (pawn-move-hop1 se) (pawn-move-hop1 nw))

(define pawn-move-R2 (pawn-move-straight2 n) (pawn-move-straight2 s)
(pawn-move-straight2 e) (pawn-move-straight2 w))

(define pawn-move-FW (pawn-move-1 ne) (pawn-move-1 nw) (pawn-move-1 se)
(pawn-move-1 sw) (pawn-move-1 n) (pawn-move-1 w) (pawn-move-1 e)
(pawn-move-1 s))

(define pawn-move-H (pawn-move-bent2 n ne) (pawn-move-bent2 n nw)
(pawn-move-bent2 e ne) (pawn-move-bent2 e se) (pawn-move-bent2 s se)
(pawn-move-bent2 s sw) (pawn-move-bent2 w sw) (pawn-move-bent2 w nw))

(define pawn-move-HL (pawn-move-bent2 n ne) (pawn-move-bent2 n nw)
(pawn-move-bent2 e ne) (pawn-move-bent2 e se) (pawn-move-bent2 s se)
(pawn-move-bent2 s sw) (pawn-move-bent2 w sw) (pawn-move-bent2 w nw) (pawn-move-hop1 n) (pawn-move-hop1 s) (pawn-move-hop1 e)
(pawn-move-hop1 w))

(define pawn-capture-1 ((verify (not-flag? immobilized))  $1 (verify enemy?) (pawn-add) ) )

(define pawn-capture-hop1 ((verify (not-flag? immobilized))  $1 (verify (not empty?)) $1 (verify enemy?) (pawn-add) ) )

(define pawn-capture-jump1 ((verify (not-flag? immobilized))  $1 (verify enemy?) capture $1 (verify empty?) (pawn-add) ) )

(define pawn-capture-straight2 ( (verify (not-flag? immobilized))  $1 (if
enemy? (pawn-add) else (verify empty?) (pawn-add) ) ) )

(define pawn-capture-leap2 ((verify (not-flag? immobilized))  $1 $2 (verify enemy?) (pawn-add) ) )

(define pawn-capture-F (pawn-capture-1 ne) (pawn-capture-1 nw)
(pawn-capture-1 se) (pawn-capture-1 sw))

(define pawn-capture-W (pawn-capture-1 n) (pawn-capture-1 w)
(pawn-capture-1 e) (pawn-capture-1 s))

(define pawn-capture-FW (pawn-capture-1 ne) (pawn-capture-1 nw)
(pawn-capture-1 se) (pawn-capture-1 sw) (pawn-capture-1 n) (pawn-capture-1
w) (pawn-capture-1 e) (pawn-capture-1 s))

(define pawn-capture-FJ (pawn-capture-1 ne) (pawn-capture-1 nw)
(pawn-capture-1 se) (pawn-capture-1 sw) (pawn-capture-hop1 ne) (pawn-capture-hop1 sw) (pawn-capture-hop1 se) (pawn-capture-hop1 nw))

(define pawn-capture-FL (pawn-capture-1 ne) (pawn-capture-1 nw)
(pawn-capture-1 se) (pawn-capture-1 sw) (pawn-capture-hop1 n) (pawn-capture-hop1 s) (pawn-capture-hop1 e) (pawn-capture-hop1 w))

(define pawn-capture-WJ (pawn-capture-1 n) (pawn-capture-1 w)
(pawn-capture-1 e) (pawn-capture-1 s) (pawn-capture-hop1 ne) (pawn-capture-hop1 sw) (pawn-capture-hop1 se) (pawn-capture-hop1 nw))

(define pawn-capture-WL (pawn-capture-1 n) (pawn-capture-1 w)
(pawn-capture-1 e) (pawn-capture-1 s) (pawn-capture-hop1 n) (pawn-capture-hop1 s) (pawn-capture-hop1 e) (pawn-capture-hop1 w))

(define pawn-capture-WC (pawn-capture-1 n) (pawn-capture-1 w)
(pawn-capture-1 e) (pawn-capture-1 s) (pawn-capture-jump1 ne) (pawn-capture-jump1 sw) (pawn-capture-jump1 se) (pawn-capture-jump1 nw))

(define pawn-capture-FT (pawn-capture-1 ne) (pawn-capture-1 sw)
(pawn-capture-1 se) (pawn-capture-1 nw) (pawn-capture-jump1 n) (pawn-capture-jump1 s) (pawn-capture-jump1 e) (pawn-capture-jump1 w))

(define pawn-capture-TC (pawn-capture-jump1 ne) (pawn-capture-jump1 sw)
(pawn-capture-jump1 se) (pawn-capture-jump1 nw) (pawn-capture-jump1 n) (pawn-capture-jump1 s) (pawn-capture-jump1 e) (pawn-capture-jump1 w))

(define pawn-capture-LT (pawn-capture-hop1 n) (pawn-capture-hop1 s)
(pawn-capture-hop1 e) (pawn-capture-hop1 w) (pawn-capture-jump1 n) (pawn-capture-jump1 s) (pawn-capture-jump1 e) (pawn-capture-jump1 w))

(define pawn-capture-JC (pawn-capture-hop1 ne) (pawn-capture-hop1 sw)
(pawn-capture-hop1 se) (pawn-capture-hop1 nw) (pawn-capture-jump1 ne) (pawn-capture-jump1 sw) (pawn-capture-jump1 se) (pawn-capture-jump1 nw))

(define pawn-capture-LC (pawn-capture-hop1 n) (pawn-capture-hop1 s)
(pawn-capture-hop1 e) (pawn-capture-hop1 w) (pawn-capture-jump1 ne) (pawn-capture-jump1 sw) (pawn-capture-jump1 se) (pawn-capture-jump1 nw))

(define pawn-capture-JT (pawn-capture-hop1 ne) (pawn-capture-hop1 sw)
(pawn-capture-hop1 se) (pawn-capture-hop1 nw) (pawn-capture-jump1 n) (pawn-capture-jump1 s) (pawn-capture-jump1 e) (pawn-capture-jump1 w))


(define Q2 (slide2 w) (slide2 e) (slide2 n) (slide2 s) (slide2 nw) (slide2
se) (slide2 ne)  (slide2 sw))

(define R3F (slide3 w) (slide3 e) (slide3 n) (slide3 s) (leap1 nw) (leap1
se) (leap1 ne)  (leap1 sw))

(define B3W (leap1 w) (leap1 e) (leap1 n) (leap1 s) (slide3 nw) (slide3 se) (slide3 ne)  (slide3 sw))

(define FWD (leap1 w) (leap1 e) (leap1 n) (leap1 s) (leap1 nw) (leap1 se)
(leap1 ne)  (leap1 sw) (leap2 w w) (leap2 e e) (leap2 n n) (leap2 s s))

(define FWA (leap1 w) (leap1 e) (leap1 n) (leap1 s) (leap1 nw) (leap1 se)
(leap1 ne)  (leap1 sw) (leap2 nw nw) (leap2 se se) (leap2 ne ne) (leap2 sw
sw))

(define FWDA (leap1 w) (leap1 e) (leap1 n) (leap1 s) (leap1 nw) (leap2 w w) (leap2 e e) (leap2 n n) (leap2 s s) (leap1 se) (leap1 ne)  (leap1 sw) (leap2 nw nw) (leap2 se se) (leap2 ne ne) (leap2 sw sw))

(define WN (leap1 w) (leap1 e) (leap1 n) (leap1 s) (leap2 n nw) (leap2 s se) (leap2 n ne)  (leap2 s sw) (leap2 w nw) (leap2 e ne) (leap2 w sw) (leap2 e se))

(define FN (leap1 nw) (leap1 se) (leap1 ne) (leap1 sw) (leap2 n nw) (leap2 s se) (leap2 n ne)  (leap2 s sw) (leap2 w nw) (leap2 e ne) (leap2 w sw) (leap2 e se))

(define FWN (leap1 w) (leap1 e) (leap1 n) (leap1 s) (leap1 nw) (leap1 se)
(leap1 ne) (leap1 sw) (leap2 n nw) (leap2 s se) (leap2 n ne)  (leap2 s sw)
(leap2 w nw) (leap2 e ne) (leap2 w sw) (leap2 e se))

(define WH (leap1 w) (leap1 e) (leap1 n) (leap1 s) (leap2b n ne) (leap2b n nw) (leap2b e ne) (leap2b e se) (leap2b s se) (leap2b s sw) (leap2b w sw) (leap2b w nw))

(define FH (leap1 nw) (leap1 se)(leap1 ne)  (leap1 sw)  (leap2b n ne) (leap2b n nw) (leap2b e ne) (leap2b e se) (leap2b s se) (leap2b s sw) (leap2b w sw) (leap2b w nw))

(define FWH (leap1 w) (leap1 e) (leap1 n) (leap1 s) (leap1 nw) (leap1 se)
(leap1 ne)  (leap1 sw)  (leap2b n ne) (leap2b n nw) (leap2b e ne) (leap2b e
se) (leap2b s se) (leap2b s sw) (leap2b w sw) (leap2b w nw))

